home *** CD-ROM | disk | FTP | other *** search
/ Amiga Plus 1995 #5 & #6 / Amiga Plus CD - 1995 - No. 5 and 6.iso / tex / mf / inputs / dc / dxillett.mf < prev    next >
Text File  |  1994-04-12  |  22KB  |  567 lines
  1. % This is DXILLETT.MF in text format, as of March 24, 1992
  2. %
  3. % DC fonts Version 1.1 (prerelease of EC fonts)
  4. %
  5. %          [ heavily borrowed from the Computer Modern Roman family of
  6. %            fonts by D. E. Knuth ]
  7. %
  8. % Content:
  9. %
  10. %   lowercase italic letters a to z
  11. %
  12.  
  13. dcchar "Italic letter a";
  14. beginchar("a",9u#,x_height#,0);
  15. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  16. adjust_fit(0,0); pickup fine.nib;
  17. pos0(hair,0); pos1(vair,90); pos2(curve,180); pos3(vair,270);
  18. pos4(stem,0); x4=x0; y4+.5stem=vround .98h;
  19. x1=x3=.5[x0,x2]; lft x2r=hround(1.5u-.5curve);
  20. rt x4r=hround(w-2.5u+.5stem);
  21. top y1r=h+oo; bot y3r=-oo; y0=y2=.5[y1,y3];
  22. filldraw stroke super_arc.e(0,1) & pulled_arc.e(1,2)
  23.  & pulled_arc.e(2,3) & super_arc.e(3,0);  % bowl
  24. x5=x4; x7=w; hook_out(5,6,7);  % closing hook
  25. filldraw circ_stroke z4e--z5e;  % stem
  26. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  27. penlabels(0,1,2,3,4,5,6,7); endchar;
  28.  
  29. dcchar "Italic letter b";
  30. beginchar("b",8u#,asc_height#,0);
  31. italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
  32. adjust_fit(0,0); pickup tiny.nib;
  33. pos1(stem,0); pos2(stem,0); x1=x2;
  34. lft x1l=hround(1.5u-.5stem); top y1=h; y2=.5x_height;
  35. filldraw stroke z1e--z2e;  % stem
  36. sloped_serif.l(1,2,a,1/3,jut,serif_drop);  % serif
  37. pickup fine.nib; pos2'(stem,-180); pos3(vair,-90);
  38. pos4(curve,0); pos5(vair,90); pos0(hair,180);
  39. z0=z2=z2'; x3=x5=.5[x2,x4]; rt x4r=hround(w-1.5u+.5curve);
  40. bot y3r=-oo; top y5r=x_height+oo; y4=y2;
  41. filldraw stroke pulled_arc.e(2',3) & pulled_arc.e(3,4)
  42.  & pulled_arc.e(4,5) & super_arc.e(5,0);  % bowl
  43. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  44. penlabels(0,1,2,3,4,5); endchar;
  45.  
  46. dcchar "Italic letter c";
  47. beginchar("c",8u#,x_height#,0);
  48. italcorr if math_fitting:1/3x_height#*slant else:x_height#*slant-u# fi;
  49. adjust_fit(0,0); pickup fine.nib;
  50. pos0(flare,0); pos1(hair,0); pos2(vair,90);
  51. pos3(curve,180); pos4(vair,270); pos5(hair,320);
  52. x2=x4=.5(w+u); rt x1r=max(rt x2,hround(w-u))+eps;
  53. lft x3r=hround(1.5u-.5curve); x5r=good.x(w-eps); x6=x5;
  54. y1=.5[bar_height,h]; top y2r=h+oo; bulb(2,1,0);  % bulb
  55. bot y4r=-oo; y3=.5[y2,y4]; top y5l=vround .5bar_height; y6=bar_height;
  56. path p; p=z4{right}..z5..z6;
  57. filldraw stroke pulled_arc.e(2,3)
  58.  & pulled_arc.e(3,4)...{direction 1 of p}z5e;  % arc
  59. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  60. penlabels(0,1,2,3,4,5,6); endchar;
  61.  
  62. dcchar "Italic letter d";
  63. beginchar("d",9u#,asc_height#,0);
  64. italcorr max(1/3x_height#*slant+.5hair#+.5u#,
  65.   h#*slant+.5stem#-2u#) if math_fitting:-.5u# fi;
  66. adjust_fit(0,0); pickup fine.nib;
  67. pos0(hair,0); pos1(vair,90); pos2(curve,180); pos3(vair,270);
  68. x0=x4; x1=x3=.5[x0,x2]; lft x2r=hround(1.5u-.5curve);
  69. x4+.5stem=hround(w-2.5u+.5stem);
  70. top y1r=x_height+oo; bot y3r=-oo; y0=y2=.5[y1,y3];
  71. filldraw stroke super_arc.e(0,1) & pulled_arc.e(1,2)
  72.  & pulled_arc.e(2,3) & super_arc.e(3,0);  % bowl
  73. x5=x0; x7=w; hook_out(5,6,7);  % closing hook
  74. pickup tiny.nib; pos5'(stem,0); pos4(stem,0);
  75. z5'=z5; top y4=h; filldraw stroke z4e--z5'e;  % stem
  76. sloped_serif.l(4,5',a,1/3,jut,serif_drop);  % serif
  77. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  78. penlabels(0,1,2,3,4,5,6,7); endchar;
  79.  
  80. dcchar "Italic letter e";
  81. beginchar("e",8u#,x_height#,0);
  82. italcorr max(1/3x_height#*slant,x_height#*slant+.5(.2[hair#,stem#])-u#);
  83. adjust_fit(0,0); pickup fine.nib;
  84. numeric heavy_hair; heavy_hair=hround .2[hair,stem];
  85. pos0(vair,-90); pos1(heavy_hair,0); pos2(vair,90);
  86. pos3(curve,180); pos4(vair,270); pos5(hair,320);
  87. x0=rt x3l; rt x1r=hround(w-1.5u+.5heavy_hair); x2=x4=.5(w+u);
  88. lft x3r=hround(1.5u-.5curve); x5r=good.x(w-eps); x6=x5;
  89. y0=y3=y6=bar_height; y1=.5[y0,y2]; top y2r=h+oo; bot y4r=-oo;
  90. top y5l=vround .5bar_height; path p; p=z4{right}..z5..z6;
  91. filldraw stroke z0e{right}...z1e{up}...pulled_arc.e(2,3)
  92.  & pulled_arc.e(3,4)...{direction 1 of p}z5e;  % arc
  93. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  94. penlabels(0,1,2,3,4,5,6); endchar;
  95.  
  96. dcchar "Italic letter f";
  97. beginchar("f",max(1.5u#,stem#)+max(3.5u#,2flare#),asc_height#,desc_depth#);
  98. italcorr asc_height#*slant+.75u#;
  99. adjust_fit(if monospace:u#,u# else: 0,0 fi); pickup fine.nib;
  100. numeric theta; z88=(.5w-.5u,h); z89=(.5w+.5u,-d); theta=angle(z88-z89);
  101. pos0(flare,0); pos1(hair,0); pos2(vair,90);
  102. pos3(.5[hair,stem],180); pos4(stem,theta+90);
  103. pos5(stem,theta-90); pos6(.5[hair,stem],0);
  104. pos7(vair,-90); pos8(hair,-180); pos9(flare,-180);
  105. rt x1r=hround(w+.25u); lft x8r=hround-.35u; x2=.6[x1,x4]; x7=.6[x8,x5];
  106. y9-.5flare=vround -.85d; y2-y0=y9-y7; top y2r=h+oo; bot y7r=-d-oo;
  107. y4=.25[x_height,h]; y5=.5[-d,y4];
  108. z4=whatever[z88,z89]; z5=whatever[z88,z89];
  109. x3=.8[x2+x4-x88,x88]; x6=.8[x7+x5-x89,x89]; y3=.8[y4,y2]; y6=.8[y5,y7];
  110. bulb(2,1,0); bulb(7,8,9);  % bulbs
  111. filldraw stroke z2e{left}...z3e...{z89-z88}z4e;  % upper arc
  112. filldraw z4r--z5l--z5r--z4l--cycle;  % stem
  113. filldraw stroke z5e{z89-z88}...z6e...{left}z7e;  % lower arc
  114. pickup crisp.nib; pos20(bar,90); pos21(bar,90);
  115. top y20r=top y21r=x_height;
  116. lft x20=lft x4r-.5stem-u; rt x21=rt x4l+.5stem+1.5u;
  117. filldraw stroke z20e--z21e;  %  crossbar
  118. math_fit(desc_depth#*slant+u#,x_height#*slant);
  119. penlabels(0,1,2,3,4,5,6,7,8,9,20,21,88,89); endchar;
  120.  
  121. dcchar "Italic letter g";
  122. beginchar("g",8u#,x_height#,desc_depth#);
  123. italcorr x_height#*slant+.5stem#-u#;
  124. adjust_fit(0,0); pickup fine.nib;
  125. pos0(hair,0); pos1(vair,90); pos2(curve,180); pos3(vair,270);
  126. x0=x4; x1=x3=.5[x0,x2]; lft x2r=hround(1.5u-.5curve);
  127. x4+.5stem=hround(w-1.5u+.5stem);
  128. top y1r=h+oo; bot y3r=0; y0=y2=.5[y1,y3];
  129. filldraw stroke super_arc.e(0,1) & pulled_arc.e(1,2)
  130.  & pulled_arc.e(2,3) & super_arc.e(3,0);  % bowl
  131. pos4(stem,0); y4+.5stem=vround .98h;
  132. pos5(stem,0); x5=x4; y5=-1/3d;
  133. pos6(vair,-90); pos7(hair,-180); pos8(flare,-180);
  134. bot y6r=-d-oo; y8-.5flare=vround -.9d;
  135. lft x8r=hround(2u-.5flare); x6=x1; bulb(6,7,8);  % bulb
  136. filldraw circ_stroke z4e---z5e...{left}z6e;  % stem and arc
  137. math_fit(-min(.3x_height#*slant+.5curve#-u#,1.5u#-desc_depth#*slant),
  138.  ic#-1/3x_height#*slant); penlabels(0,1,2,3,4,5,6,7,8); endchar;
  139.  
  140. dcchar "Italic letter h";
  141. beginchar("h",9u#,asc_height#,0);
  142. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  143. adjust_fit(0,0); pickup tiny.nib;
  144. pos1(stem,0); pos2(stem,0); x1=x2;
  145. lft x1l=hround(1.5u-.5stem); top y1=h; y2-.5stem=-oo;
  146. filldraw circ_stroke z2e--z1e;  % left stem
  147. sloped_serif.l(1,2,a,1/3,jut,serif_drop);  % serif
  148. pickup fine.nib; x4+.5stem=hround(w-2.5u+.5stem);
  149. x5=x4-.25u; ital_arch(2,3,4);  % arch
  150. x7=w; hook_out(5,6,7)(skewed);  % closing hook
  151. filldraw stroke z4e{down}..{-u,-x_height}z5e;  % right stem
  152. math_fit(0,ic#); penlabels(1,2,3,4,5,6,7); endchar;
  153.  
  154. dcchar "Italic letter i";
  155. beginchar("i",5u#,min(asc_height#,10/7x_height#+.5flare#),0);
  156. italcorr max(1/3x_height#*slant+.5hair#+.5u#,h#*slant+.5flare#-2u#);
  157. adjust_fit(if monospace:u#,u# else: 0,0 fi); pickup fine.nib;
  158. x0=0; x5=w; x2=.5w+.25u; x3=.5w-.25u;
  159. if classic_serif:
  160.   hook_out(3,4,5)(skewed);  % hooks
  161.   top y2=x_height;
  162.   pos2(stem,0);
  163.   sloped_serif.l(2,3,a,1/3,jut,serif_drop);
  164. else:
  165.   hook_in(0,1,2)(skewed);
  166.   hook_out(3,4,5)(skewed);  % hooks
  167. fi
  168. filldraw stroke z2e--z3e;  % stem
  169. pos8(flare,0); pos9(flare,90);
  170. x8=.5w if not monospace:-.4(h-x_height)*slant fi; top y9r=h+1;
  171. if classic_serif: else:
  172.  if bot y9l-top y1<slab: y9l:=min(y9r-eps,y1+fine+slab); fi
  173. fi
  174. x8=x9; y8=.5[y9l,y9r]; dot(8,9);  % dot
  175. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  176. penlabels(0,1,2,3,4,5,8,9); endchar;
  177.  
  178. dcchar "Italic letter j";
  179. beginchar("j",5u#,min(asc_height#,10/7x_height#+.5flare#),desc_depth#);
  180. italcorr h#*slant+.5stem#-u#;
  181. adjust_fit(if monospace:2u#,.5u# else: 0,0 fi); pickup fine.nib;
  182. x0=0; x2=x3; pos3(stem,0); lft x3l=hround(w-1.5u-.5stem);
  183. if classic_serif:
  184.   pos4(vair,-90); pos5(hair,-180); pos6(flare,-180);
  185.   bot y3=-1/3d; bot y4r=-d-oo; y6-.5flare=-vround.9d;
  186.   top y2=x_height;
  187.   pos2(stem,0);
  188.   sloped_serif.l(2,3,a,1/3,jut,serif_drop);
  189. else:
  190.   hook_in(0,1,2);  % opening hook
  191.   pos4(vair,-90); pos5(hair,-180); pos6(flare,-180);
  192.   bot y3=-1/3d; bot y4r=-d-oo; y6-.5flare=-vround.9d;
  193. fi
  194. x4=1/3(w-u); lft x5r=min(hround-.5u,lft x5r+x4-x5l-eps);
  195. filldraw stroke z2e---z3e...{left}z4e;  % stem and arc
  196. bulb(4,5,6);  % bulb
  197. pos8(flare,0); pos9(flare,90);
  198. rt x8r=rt x2r if not monospace:-.6(h-x_height)*slant fi; top y9r=h+1;
  199. if classic_serif: else:
  200.    if bot y9l-top y1<slab: y9l:=min(y9r-eps,y1+fine+slab); fi
  201. fi
  202. x8=x9; y8=.5[y9l,y9r]; dot(8,9);  % dot
  203. math_fit(desc_depth#*slant,x_height#*slant+.5stem#-u#);
  204. penlabels(0,1,2,3,4,5,6,8,9); endchar;
  205.  
  206. dcchar "Italic letter k";
  207. beginchar("k",8u#,asc_height#,0);
  208. italcorr x_height#*slant;
  209. adjust_fit(0,0); pickup tiny.nib;
  210. pos1(stem,0); pos2(stem,0); x1=x2;
  211. lft x1l=hround(1.5u-.5stem); top y1=h; y2-.5stem=-oo;
  212. filldraw circ_stroke z2e--z1e;  % left stem
  213. sloped_serif.l(1,2,a,1/3,jut,serif_drop);  % serif
  214. pickup fine.nib; pos3(vair,90); x3=x1; y3=bar_height;
  215. pos4(vair,90); x4=w-2u; top y4r=x_height+oo;
  216. filldraw stroke z3e{right}..{right}z4e;  % upper diagonal
  217. pos5(hair,0); pos6(flare,0);
  218. rt x5r=hround(w-.5u); y5+.5flare=vround(bot y4l-.03x_height);
  219. bulb(4,5,6);  % bulb
  220. pos7(stem,0); pos8(vair,90); pos9(hair,180);
  221. x9+.5hair=hround(w+.5hair-eps); y9=1/3x_height;
  222. lft x7l=hround(w-2.75u-.5stem); y7=1/2y3; x8=w-1.2u; bot y8l=-oo;
  223. filldraw stroke z3e{right}...z7e{down}
  224.  ...z8e{right}...{up}z9e;  % lower diagonal
  225. math_fit(0,1/3x_height#*slant+.5hair#+.5u#);
  226. penlabels(1,2,3,4,5,6,7,8,9); endchar;
  227.  
  228. dcchar "Italic letter l";
  229. beginchar("l",4u#,asc_height#,0); l_width#:=4u#;
  230. italcorr max(1/3x_height#*slant+.5hair#+.5u#,
  231.  asc_height#*slant+.5stem#-2u#) if math_fitting:+.5u# fi;
  232. adjust_fit(if monospace:u#,u# else: 0,0 fi); pickup fine.nib;
  233. x2-.5stem=hround(1.5u-.5stem); x4=w; hook_out(2,3,4);  % closing hook
  234. pickup tiny.nib; pos1(stem,0); pos2'(stem,0); z2'=z2;
  235. top y1=h; x1=x2; filldraw stroke z1e--z2e;  % stem
  236. sloped_serif.l(1,2,a,1/3,jut,serif_drop);  % serif
  237. math_fit(-.5u#,1/3x_height#*slant+.5hair#+u#); penlabels(1,2,3,4); endchar;
  238.  
  239. dcchar "Italic letter m";
  240. beginchar("m",15u#,x_height#,0);
  241. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  242. adjust_fit(if monospace:-1.5u#,-2u# else: 0,0 fi); pickup fine.nib;
  243. numeric shaved_stem; shaved_stem=mfudged.stem;
  244. save stem; stem=shaved_stem;
  245. pos2(stem,0); x1=x2;
  246. y2-.5stem=-oo;
  247. if monospace: pos1(stem,0); lft x1l=hround(2.5u-.5stem); top y1=h;
  248. else:
  249.   x0=0; lft x2l=hround(2.5u-.5stem);
  250.   if classic_serif:
  251.     top y1=h; pos1(stem,0);
  252.     sloped_serif.l(1,2,a,1/3,jut,serif_drop);
  253.   else:
  254.     hook_in(0,a,1);
  255.   fi
  256. fi  % opening hook
  257. filldraw circ_stroke z2e--z1e;  % left stem
  258. x4+.5stem=hround(.5w+.5stem); ital_arch(2,3,4);  % left arch
  259. pos5(stem,0); y5=y2; x5=x4;
  260. filldraw circ_stroke z5e--z4e;  % middle stem
  261. x7+.5stem=hround(w-2.5u+.5stem);
  262. x8=x7-.25u; ital_arch(5,6,7);  % right arch
  263. if monospace: pos9(vair,90); x9=good.x .5[x8,w]; bot y9l=0; y8=1/3h;
  264.  pos8(stem,0); filldraw stroke z8e{-u,-x_height}...{right}z9e; % terminal
  265. else: x9=w; hook_out(8,b,9)(skewed); fi  % closing hook
  266. filldraw stroke z7e{down}..{-u,-x_height}z8e;  % right stem
  267. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  268. penlabels(0,a,1,2,3,4,5,6,7,8,9); endchar;
  269.  
  270. dcchar "Italic letter n";
  271. beginchar("n",10u#,x_height#,0);
  272. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  273. adjust_fit(0,0); pickup fine.nib;
  274. x0=0; x1=x2; pos2(stem,0); lft x2l=hround(2.5u-.5stem); y2-.5stem=-oo;
  275. if classic_serif:
  276.   top y1=h; pos1(stem,0);
  277.   sloped_serif.l(1,2,a,1/3,jut,serif_drop);
  278. else:
  279.   hook_in(0,a,1);  % opening hook
  280. fi
  281. filldraw circ_stroke z2e--z1e;  % left stem
  282. x4+.5stem=hround(w-2.5u+.5stem); x5=x4-.25u; ital_arch(2,3,4);  % arch
  283. x7=w; hook_out(5,6,7)(skewed);  % closing hook
  284. filldraw stroke z4e{down}..{-u,-x_height}z5e;  % right stem
  285. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  286. penlabels(0,a,1,2,3,4,5,6,7); endchar;
  287.  
  288. dcchar "Italic letter o";
  289. beginchar("o",9u#,x_height#,0);
  290. italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
  291. adjust_fit(0,0); pickup fine.nib;
  292. pos1(vair,90); pos2(curve,180); pos3(vair,270); pos4(curve,360);
  293. x1=x3=.5w; lft x2r=hround(1.5u-.5curve); x4=w-x2;
  294. top y1r=h+oo; y2=y4=.5[y1,y3]; bot y3r=-oo;
  295. filldraw stroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
  296.  & pulled_arc.e(3,4) & pulled_arc.e(4,1); % bowl
  297. math_fit(-.3x_height#*slant+.5curve#-u#,ic#); penlabels(1,2,3,4); endchar;
  298.  
  299. dcchar "Italic letter p";
  300. beginchar("p",9u#,x_height#,desc_depth#);
  301. italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
  302. adjust_fit(0,0); pickup fine.nib;
  303. x0=0; x2-.5stem=hround(2.5u-.5stem);
  304. if classic_serif:
  305.   pos2(stem,0);  % done previous by hook_in
  306.   y2=3/4x_height; % dito
  307. else:
  308.   hook_in(0,1,2);  % opening hook
  309. fi
  310.  
  311. pos4(hair,-180);
  312. pos5(vair,-90);
  313. pos6(curve,0);
  314. pos7(vair,90);
  315. x4=x2; rt x6r=hround(w-1.5u+.5curve); x5=x7=.5[x4,x6];
  316. bot y5r=-oo; top y7r=h+oo; y4=y6=.5[y5,y7];
  317.  
  318. if classic_serif:
  319.   x8=x2; pos8(stem,0); top y8=h;
  320.   sloped_serif.l(8,4,c,1/3,jut,serif_drop);
  321. fi
  322.  
  323. filldraw stroke super_arc.e(4,5) & pulled_arc.e(5,6)
  324.  & pulled_arc.e(6,7) & super_arc.e(7,4);  % bowl
  325. pickup tiny.nib; pos2'(stem,0); pos3(stem,0);
  326. z2=z2'; x3=x2; bot y3=-d;
  327. if classic_serif:
  328.  filldraw stroke z8e--z3e;  % stem
  329. else:
  330.  filldraw stroke z2'e--z3e;  % stem
  331. fi
  332. dish_serif(3,2',a,1/3,.75jut,b,1/3,jut);  % serif
  333. math_fit(-min(2/3x_height#*slant-.5hair#-.5u#,
  334.  2u#-.5stem#-desc_depth#*slant),ic#);
  335. penlabels(0,1,2,3,4,5,6,7 if classic_serif: ,8 fi); endchar;
  336.  
  337. dcchar "Italic letter q";
  338. beginchar("q",8u#,x_height#,desc_depth#);
  339. italcorr x_height#*slant+.5stem#-u#;
  340. adjust_fit(0,0); pickup fine.nib;
  341. pos0(hair,0); pos1(vair,90); pos2(curve,180); pos3(vair,270);
  342. x0=x4; x1=x3=.5[x0,x2]; lft x2r=hround(1.5u-.5curve);
  343. x4+.5stem=hround(w-1.5u+.5stem)+eps;
  344. top y1r=h+oo; bot y3r=-oo; y0=y2=.5[y1,y3];
  345. filldraw stroke super_arc.e(0,1) & pulled_arc.e(1,2)
  346.  & pulled_arc.e(2,3) & super_arc.e(3,0);  % bowl
  347. pickup tiny.nib; pos4(stem,0); pos5(stem,0);
  348. x4=x5; x6=x5r; top y6=h+oo; bot y4=-d;
  349. y5=ypart(((x4l,0)--(x4l,y6))intersectionpoint super_arc.r(0,1));
  350. filldraw z6{2(x5l-x6),y5-y6}...z5l---z4l--z4r--cycle;  % stem
  351. dish_serif(4,5,a,1/3,jut,b,1/3,jut);  % serif
  352. math_fit(-.3x_height#*slant+.5curve#-u#,ic#-1/3x_height#*slant);
  353. penlabels(0,1,2,3,4,5,6,7,8); endchar;
  354.  
  355. dcchar "Italic letter r";
  356. beginchar("r",5.5u#+max(1.75u#,flare#),x_height#,0);
  357. italcorr x_height#*slant;
  358. adjust_fit(if monospace:.25u#,.5u# else: 0,0 fi); pickup fine.nib;
  359. x0=0; x2=x3; pos3(stem,0); lft x3l=hround(2.5u-.5stem); y3-.5stem=-oo;
  360. if classic_serif:
  361.   pos2(stem,0);
  362.   y2=1/4x_height; % dito
  363.   x8=x2; pos8(stem,0); top y8=h;
  364.   sloped_serif.l(8,3,c,1/3,jut,serif_drop);
  365.   filldraw circ_stroke z8e--z3e;  % left stem
  366. else:
  367.   hook_in(0,1,2);  % opening hook
  368.   filldraw circ_stroke z3e--z2e;  % left stem
  369. fi
  370. pos3'(hair,180); z3'=z3; pos4(vair,90); pos5(hair,0); pos6(flare,0);
  371. x4=w-.5u-max(1.75u,flare); rt x5r=hround(r-.5u); top y4r=h+oo;
  372. filldraw stroke z3'e{up}...z4e{right};  % link
  373. y6+.5flare=vround(bot y4l-.03x_height); bulb(4,5,6);  % bulb
  374. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#-.5u#);
  375. penlabels(0,1,2,3,4,5,6); endchar;
  376.  
  377.  
  378. dcchar "Italic letter s";
  379. beginchar("s",5.25u#+max(1.75u#,flare#),x_height#,0);
  380. italcorr x_height#*slant-.5u#;
  381. adjust_fit(0,0); pickup fine.nib;
  382. numeric theta; theta=90-angle(40u,h); slope:=-h/40u;  % angle at middle
  383. pos2(vair,-90); pos0(max(fine.breadth,ess),theta); pos7(vair,-90);
  384. x2l=x0=x7=.5w; top y2l=h+oo; bot y7r=-oo;
  385. y0-.5ess=y7l+.55(y2r-y7l-ess);
  386. lft x3l=hround u-eps; rt x6r=hround(w-.5u)+eps;
  387. x3r-x3l=x6r-x6l=hround .5[vair,ess]-fine;
  388. ellipse_set(2l,3l,4l,0l); ellipse_set(2r,3r,4r,0r); y3=y3r;
  389. ellipse_set(7l,6l,5l,0l); ellipse_set(7r,6r,5r,0r); y6=y6r;
  390. interim superness:=more_super;
  391. filldraw stroke super_arc.e(2,3) & z3e{down}
  392.  ..z4e---z5e..z6e{down} & super_arc.e(6,7);  % main stroke
  393. pos1(hair,0); pos10(hround .75[hair,flare],0);
  394. pos2'(vair,90); z2'=z2;
  395. pos8(hair,-180); pos9(flare,-180);
  396. rt x10r=hround(w-u)+2eps; lft x9r=hround .5u-2eps; y10=.78h; y9=.25h;
  397. bulb(2',1,10); bulb(7,8,9);  % bulbs
  398. math_fit(0,ic#); penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  399.  
  400. dcchar "Italic letter t";
  401. beginchar("t",5.5u#,min(asc_height#,10/7x_height#),0);
  402. italcorr max(1/3x_height#*slant+.5hair#+.5u#,x_height#*slant-.25u#);
  403. adjust_fit(if monospace:u#,u# else:0,0 fi); pickup fine.nib;
  404. pos1(stem,0); lft x1l=hround(2u-.5stem); y1+.5stem=h+oo;
  405. x2=x1; x4=w; hook_out(2,3,4);  % closing hook
  406. if classic_serif:
  407.    filldraw stroke z1e--z2e;  % stem
  408. else:
  409.    filldraw circ_stroke z1e--z2e;  % stem
  410. fi
  411. pickup crisp.nib; pos5(bar,90); pos6(bar,90);
  412. lft x5=hround-.75u; rt x6=hround(w-.75u); top y5r=top y6r=x_height;
  413. filldraw stroke z5e--z6e;  % crossbar
  414. math_fit(1.25u#-x_height#*slant,ic#); penlabels(1,2,3,4,5,6); endchar;
  415.  
  416. dcchar "Italic letter u";
  417. beginchar("u",9.5u#,x_height#,0);
  418. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  419. adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
  420. if classic_serif:
  421.    x0=0; x2=x3; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  422.    pos2(stem,0);
  423.    top y2=h;
  424. else:
  425.   x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  426.   hook_in(0,1,2)(skewed);  % opening hook
  427. fi
  428. pos2'(stem,-180); z2'=z2;
  429. pos4(vair,-90); pos5(hair,0); x4=.5[x3,x5];
  430. pos6(stem,0); rt x6r=hround(w-2.5u+.5stem);
  431. x5=x6=x7; x9=w; hook_out(7,8,9);  % closing hook
  432. y3=.7[y4,y5]; bot y4r=-oo; y5=.57h; y6+.5stem=h;
  433. if classic_serif:
  434.   filldraw stroke z2
  435.    ...super_arc.e(3,4)...{up}z5e; % left stem and arc
  436. else:
  437.   filldraw stroke z2'e{-u,-x_height}
  438.    ...super_arc.e(3,4)...{up}z5e; % left stem and arc
  439. fi
  440. filldraw circ_stroke z6e--z7e;  % right stem
  441. if classic_serif: sloped_serif.l(2,3,a,1/3,jut,serif_drop); fi
  442. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  443. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  444.  
  445.  
  446. dcchar "Italic letter v";
  447. beginchar("v",8u#,x_height#,0);
  448. italcorr x_height#*slant;
  449. adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
  450. x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  451. if classic_serif:
  452.   pos2(stem,0);
  453.   top y2=h;
  454. else:
  455.   hook_in(0,1,2)(skewed);  % opening hook
  456. fi
  457. pos2'(stem,-180); z2'=z2; pos4(vair,-90); pos5(hair,0);
  458. x4=.5w+u; rt x5r=hround(w-.5u); y3=.7[y4,y5]; bot y4r=-oo; y5=.57h;
  459. filldraw stroke z2'e{-u,-x_height}...super_arc.e(3,4)
  460.  ..tension atleast 1.05..{up}z5e; % left stem and arc
  461. v_bulb(5,6);  % closing bulb
  462. if classic_serif: sloped_serif.l(2,3,a,1/3,jut,serif_drop); fi
  463. math_fit(-2/3x_height#*slant+.5hair#+.5u#,2/3ic#);
  464. penlabels(0,1,2,3,4,5,6); endchar;
  465.  
  466. dcchar "Italic letter w";
  467. beginchar("w",12u#,x_height#,0);
  468. italcorr x_height#*slant;
  469. adjust_fit(if monospace:-1.5u#,-u# else: 0,0 fi);
  470. pickup fine.nib; interim superness:=more_super; begingroup
  471. forsuffixes $=hair,stem: shaved$:=mfudged$; save $; $=shaved$; endfor
  472. x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  473. if monospace: pos1(vair,90); x1=good.x .5[x0,x2]; top y1r=h; y2=2/3h;
  474.  pos2(stem,0); filldraw stroke z1e{right}...{-u,-x_height}z2e;
  475. else:
  476. if classic_serif:
  477.   pos2(stem,0);
  478.   top y2=h;
  479. else:
  480.   hook_in(0,1,2)(skewed);
  481. fi
  482. fi  % opening hook
  483. pos2'(stem,-180); z2'=z2;
  484. pos4(vair,-90); pos5(hair,0);
  485. x4=.6[x2,x5]; x5=x6=x7; pos6(stem,-180); pos7(stem,-180);
  486. y3=.7[y4,y5]; bot y4r=-oo; y5=.57h;
  487. rt x6l=hround(rt x6l+.5w+.75u-x6); y6+.5stem=h; y7=y3;
  488. pos8(vair,-90); pos9(hair,0);
  489. x8=w-2.75u; rt x9r=hround(w-.5u); bot y8r=-oo; y9=y5;
  490. if classic_serif: sloped_serif.l(2,3,a,1/3,jut,serif_drop); fi
  491. filldraw stroke z2'e{-u,-x_height}
  492.  ...super_arc.e(3,4)...{up}z5e; % left stem and arc
  493. filldraw circ_stroke z6e..super_arc.e(7,8)...{up}z9e;  % middle stem and arc
  494. v_bulb(9,10);  % closing bulb
  495. endgroup; math_fit(-2/3x_height#*slant+.5hair#+.5u#,3/4ic#);
  496. penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  497.  
  498. dcchar "Italic letter x";
  499. beginchar("x",6.5u#+max(1.5u#,flare#),x_height#,0);
  500. italcorr max(1/3x_height#*slant+.5hair#+.5u#,x_height#*slant+.25u#);
  501. adjust_fit(0,0); pickup fine.nib;
  502. pos0(hair,180); pos1(vair,90); pos2(stem,0);
  503. pos3(stem,-180); pos4(vair,-90); pos5(hair,0);
  504. y0=y2=2/3h; y3=y5=1/3h; top y1r=h+oo; bot y4r=-oo;
  505. rt x2r=hround(.5w+.5stem-eps); x2=x3;
  506. x0-.5hair=hround-.5hair; x5+.5hair=hround(w+.5hair-eps);
  507. x1=.5[x0,x2]; x4=.5[x3,x5];
  508. filldraw stroke z0e{up}...pulled_arc.e(1,2); % opening hook
  509. filldraw z2l--z3r--z3l--z2r--cycle;  % stem
  510. filldraw stroke pulled_arc.e(3,4)...{up}z5e;  % closing hook
  511. pos3'(hair,180); pos6(hair,180); pos7(vair,90);
  512. pos8(hair,0); pos9(flare,0);
  513. x3'l=x6l=x3l; y3'=y3; y6=3/4h; x7=.5[x8,x2]; top y7r=h+oo;
  514. rt x8r=hround(w-.25u); y8+.5flare=vround(bot y7l-.03x_height);
  515. filldraw stroke z3'e---z6e...{right}z7e; bulb(7,8,9);  % upper link and bulb
  516. pos2'(hair,0); pos16(hair,0); pos17(vair,-90);
  517. pos18(hair,-180); pos19(flare,-180);
  518. x2'l=x16l=x2l; y2'=y2; y16=1/4h; x17=.5[x18,x3]; bot y17r=-oo;
  519. lft x18r=hround.25u; y18-.5flare=vround(top y17l+.03x_height);
  520. filldraw stroke z2'e---z16e...{left}z17e; bulb(17,18,19); % lower link and bulb
  521. math_fit(0,ic#); penlabels(0,1,2,3,4,5,6,7,8,9,16,17,18,19); endchar;
  522.  
  523. dcchar "Italic letter y";
  524. beginchar("y",8.5u#,x_height#,desc_depth#);
  525. italcorr x_height#*slant+.5stem#-u#;
  526. adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
  527. x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  528. if classic_serif:
  529.   pos2(stem,0);
  530.   top y2=h;
  531. else:
  532.   hook_in(0,1,2)(skewed);  % opening hook
  533. fi
  534. pos2'(stem,-180); z2'=z2;
  535. pos4(vair,-90); pos5(hair,0); x4=.5[x3,x5];
  536. pos6(stem,0); rt x6r=hround(w-1.5u+.5stem);
  537. pos7(stem,0); pos8(vair,-90);
  538. y3=.7[y4,y5]; bot y4r=-oo; y5=.57h; y6+.5stem=h;
  539. y7=0; bot y8r=-d-oo; x5=x6=x7; x8=.5w;
  540. pos9(hair,-180); pos10(flare,-180); y9=-.5d;
  541. lft x9r=hround(2.75u-.5flare); bulb(8,9,10);  % bulb
  542. filldraw stroke z2'e{-u,-x_height}
  543.  ...super_arc.e(3,4)...{up}z5e; % left stem and arc
  544. filldraw circ_stroke z6e---z7e...{left}z8e;  % right stem and link
  545. if classic_serif: sloped_serif.l(2,3,a,1/3,jut,serif_drop); fi
  546. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#-1/3x_height#*slant);
  547. penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  548.  
  549. dcchar "Italic letter z";
  550. beginchar("z",5.5u#+max(1.5u#,stem#),x_height#,0);
  551. italcorr x_height#*slant+.5hair#;
  552. adjust_fit(if monospace:.5u#,.5u# else: 0,0 fi); pickup fine.nib;
  553. pos1(hair,0); pos2(stem,-90); pos3(vair,-90); pos4(hair,0);
  554. lft x1l=hround(u-.5hair); x2=2.5u; x3=w-2u; rt x4r=hround(w-.5u);
  555. top y1=.78h; top y2l=top y4=h+oo; y3=.825h;
  556. pos5(hair,0); pos6(vair,-90); pos7(stem,-90); pos8(hair,0);
  557. x5=x1; x6=2.5u; x7=w-2u; x8+.5hair=hround(w+.5hair-eps);
  558. bot y5=bot y7r=-oo; y6=.175h; bot y8=.31h;
  559. pair p; p=(z4-z5) yscaled 2;
  560. filldraw stroke z1e{up}...z2e{right}..z3e{right}...{p}z4e;  % upper bar
  561. filldraw stroke z5e{p}...z6e{right}..{right}z7e...{up}z8e;  % lower bar
  562. filldraw stroke z5e{p}..{p}z4e;  % diagonal
  563. math_fit(0,1/3x_height#*slant+.5hair#+.5u#);
  564. penlabels(1,2,3,4,5,6,7,8); endchar;
  565.  
  566. endinput;
  567.